قاعدة المعارف KB0206

يستخدم think-cell لون خط غير صحيح

المشكلة

لا يستخدم think-cell لون النص الرئيسي المحدد في قالب PowerPoint لدي.

الحل

حدثت هذه المشكلة في السابق بسبب خطأ في PowerPoint. اعتبارًا من يوليو 2017، قامت Microsoft بإصلاح المشكلة في Office 365 وOffice 2016. استلمت إصدارات Office 365 وOffice 2016 بتكنولوجيا التشغيل الفوري الإصلاح مع التحديث إلى الإصدار 1706 (النسخة 8229.2073). تم تضمين الإصلاح الخاص بإصدار Office 2016 المستند إلى MSI في KB3203481.

الشرح والحل البديل في حالة عدم إصلاح إصدار Office الخاص بك

يحاول think-cell تحديد لون الخط الصحيح استنادًا إلى ألوان الخط التي يوفرها قالب PowerPoint. تقوم إصدارات PowerPoint التي تحتوي على الخطأ بإبلاغ think-cell بقيم غير صحيحة للون الخط إذا كانت بعض العناصر النائبة مفقودة في شريحة المستوى العلوي للشريحة الرئيسية. يمكن تكرار هذه المشكلة دون استخدام think-cell.

تكرار الخطأ دون استخدام think-cell

تقوم وحدة الماكرو التالية بإدراج شريحة جديدة مع مربع نص يعرض قيم لون الخط الناتجة لكل TextStyleLevel للشريحة الرئيسية في PowerPoint. "يعرض TextStyleLevel [1]" لون الخط الرئيسي الذي يوفره PowerPoint.

  1. افتح ملف PowerPoint المتأثر بالمشكلة وافتح محرر VBA بواسطة الضغط على المفتاحين Alt+F11
  2. في محرر VBA، حدد العرض التقديمي ثم انقر فوق إدراجوحدة نمطية جديدة
  3. الصق وحدة الماكرو التالية وأغلق محرر VBA
  4. في نافذة العرض التقديمي في PowerPoint، اضغط على المفتاحين Alt+F8 لفتح النافذة وحدات ماكرو
  5. حدد عرض وانقر فوق تشغيل
Function AppendToTextRange(txtfrm2 As PowerPoint.TextFrame2) As Office.TextRange2
    Set AppendToTextRange = _
	txtfrm2.TextRange.Characters(txtfrm2.TextRange.Length + 1, 0)
End Function

Sub Demonstrate()
    Dim pres As PowerPoint.Presentation
    Set pres = ActivePresentation
    
    Dim sld As PowerPoint.Slide
    Set sld = pres.Slides.Add(pres.Slides.Count + 1, PowerPoint.ppLayoutBlank)
    sld.Select
    
    Dim mstr As PowerPoint.Master
    Set mstr = sld.Design.SlideMaster
    
    Dim shp As PowerPoint.Shape
    Set shp = sld.Shapes.AddShape(Office.msoShapeRectangle, 50, 50, _
    pres.PageSetup.SlideWidth / 2 - 50, pres.PageSetup.SlideHeight - 100)
    shp.Fill.ForeColor.RGB = RGB(255, 255, 122) 'light yellow backgound

    Dim txtfrm2 As PowerPoint.TextFrame2
    Set txtfrm2 = shp.TextFrame2
    
    Dim txtrng2 As Office.TextRange2
    Dim i As Integer
    i = 1
    Dim txtlvl As PowerPoint.TextStyleLevel
    For Each txtlvl In mstr.TextStyles(PowerPoint.ppBodyStyle).Levels
        Set txtrng2 = AppendToTextRange(txtfrm2)
        txtrng2.Text = "TextStyleLevel[" & i & "] has color " & vbCr
        txtrng2.Font.Fill.Solid
        txtrng2.Font.Fill.ForeColor.ObjectThemeColor = Office.msoThemeColorText1
        
        Set txtrng2 = AppendToTextRange(txtfrm2)
        Dim col As PowerPoint.ColorFormat
        
        Set col = txtlvl.Font.Color
        If PowerPoint.ppSchemeColorMixed = col.Type Then
            txtrng2.Text = "MIXED (should not occur)" & vbCr & vbCr
        Else
            If Office.msoNotThemeColor = col.ObjectThemeColor Then
                Dim nRgb As Long
                nRgb = col.RGB()
                txtrng2.Text = "RGB: " & (nRgb Mod 256) & "/" & ((nRgb \ 256) _
                Mod 256) & "/" & (nRgb \ 256 \ 256) & vbCr & vbCr
                txtrng2.Font.Fill.ForeColor.RGB = nRgb
            Else
                txtrng2.Text = "ObjectThemeColor: " & col.ObjectThemeColor _
                & vbCr & vbCr
                txtrng2.Font.Fill.ForeColor.ObjectThemeColor = col.ObjectThemeColor
            End If
        End If
        i = i + 1
    Next txtlvl
End Sub

الحل البديل

إدراج العناصر النائبة المفقودة في الشريحة الرئيسية للعرض التقديمي في PowerPoint لديك:

  1. افتح الشريحة الرئيسية: PowerPoint ← عرضطرق العرض الرئيسيةالشريحة الرئيسية
  2. انتقل إلى شريحة المستوى العلوي في الشريط الجانبي المصغر
  3. في معظم الحالات، يمكن حل المشكلة عن طريق إدراج العنصر النائب المفقود لكل من نص و/أو عنوان:
    تخطيط رئيسيتخطيط رئيسي ← حددنص و/أو عنوانموافق
  4. أغلق الشريحة الرئيسية: إغلاقإغلاق العرض الرئيسي
  5. أدرج مخططًا جديدًا أو قم بتحديث المخططات الموجودة، على سبيل المثال، عن طريق سحبها إلى موضع جديد

في حالة استمرار حدوث المشكلة بعد ذلك، يرجى تكرار هذه الخطوات مع تحديد كل العناصر النائبة المفقودة في الخطوة رقم 3. قد تحتوي القوالب أو العروض التقديمية على أكثر من شريحة رئيسية واحدة متأثرة بالمشكلة؛ قم بتطبيق الحل البديل عليها جميعًا.

قد ترغب في تضمين هذا الحل البديل في قالب PowerPoint لديك أو يمكنك الاتصال بالشخص المسؤول عن قوالب PowerPoint لديك من أجل تحديث القالب الافتراضي.

إذا كانت شركتك تمتلك تعاقدًا مع دعم Microsoft Office وتريد مطالبة Microsoft بإصلاح إصدار Office الخاص بك أيضًا، فيرجى ذكر رقم طلب Microsoft الخاص بنا 116080514511540.

الاتصال بالدعم

إذا استمرت مشكلة عدم استخدام think-cell للون الخط الصحيح بالرغم من استخدام إصدار Office تم إصلاحه أو تطبيق الحل البديل، فيرجى إرسال مثال لشريحة إلى فريق الدعم الخاص بنا وإخبارنا بلون الخط المفضل لديك.

مشاركة